Arduino：有紅燈倒數計時的紅綠燈控制電路

作者： Danny Yang

 




功能


一開始縱向的紅色 LED 亮，伴隨著從 120 秒開始的倒數計時 ( 倒數秒數為 3 位數時不顯示，倒數至 2 位數即 99 秒時才開始顯示 )，且橫向的綠色 LED 同時跟著亮。當縱向的紅色 LED 倒數至 3 秒時，橫向的綠色 LED 熄滅，且橫向的黃色 LED 亮；當縱向的紅色 LED 倒數至 0 秒時 ( 不顯示 )，縱向的紅色 LED 熄滅，轉而縱向的綠色 LED 亮，且橫向的紅色 LED 亮，伴隨著從 120 秒開始的倒數計時( 一樣倒數秒數為 3 位數時不顯示，倒數至 2 位數即 99 秒時才開始顯示 )。當橫向的紅色 LED 倒數至 3 秒時，縱向的綠色 LED 熄滅，縱向的的黃色 LED 亮；當橫向的紅色 LED 倒數至 0 秒時 ( 不顯示 )，橫向的紅色 LED 熄滅，縱向的綠色 LED 亮，如此周而復始。



電路圖


有紅燈倒數計時的紅綠燈控制電路圖
圖一  有紅燈倒數計時的紅綠燈控制電路圖



程式碼


 C/C++
bool RedOnLongitudinal =  true;     /* 初始狀態為縱向紅燈亮 */
const int scanPin[] = {5, 6, 7, 8};     /* 七段顯示器掃描訊號的輸出接腳為第 5、6、7、8 腳 */
const int dataPin = 10, latchPin = 11, clockPin = 12;  /* 串列資料輸出接腳為第 10 腳；栓鎖訊號輸
                                                                                       出接腳為第 11 腳；移位脈波輸出接腳為第
                                                                                       12 腳 */

/* 數字 0 至 9 的共陽極七段顯示碼  */
const int sevenSegCode[ ] = {0xC0, 0xF9, 0xA4, 0xB0, 0x99, 0x92, 0x82, 0xF8, 0x80, 0x90};

int dataOut[4] = {0, 0, 0, 0};  /* 縱向兩位數以及橫向兩位數的輸出輸出緩衝區，由左至右順序為
                                                縱向的個位 (dataOut[0])、十位 (dataOut[1]) 、與橫向的個位
                                                (dataOut[2])、十位 (dataOut[3]) */

unsigned long previousTime;  /* 暫存系統時間的變數 */
unsigned long nowTime;         /* 暫存系統時間的變數 */
int second = 0;                        /* 紀錄秒數的變數 */

int GreenLight_1 = 2;              /*  輸出控制縱向綠色 LED 亮滅的輸出接腳為第 2 腳 */
int YellowLight_1 = 3;              /*  輸出控制縱向黃色 LED 亮滅的輸出接腳為第 3 腳 */
int RedLight_1 = 4;                  /*  輸出控制縱向紅色 LED 亮滅的輸出接腳為第 4 腳 */

int GreenLight_2 = A0;            /*  輸出控制橫向綠色 LED 亮滅的輸出接腳為第 A0 腳 */
int YellowLight_2 = A1;            /*  輸出控制橫向黃色 LED 亮滅的輸出接腳為第 A1 腳 */
int RedLight_2 = A2;                /*  輸出控制橫向紅色 LED 亮滅的輸出接腳為第 A2 腳 */

int RedLightLastingSecond = 120;         /*  紅色 LED 亮的持續秒數 */
int GreenLightLastingSecond = 117;      /*  綠色 LED 亮的持續秒數 */
int YellowLightLastingSecond = 3;         /*  黃色 LED 亮的持續秒數 */
                                                               /* 〔注意〕：GreenLightLastingSecond +
                                                                      YellowLightLastingSecond  必須等於
                                                                      RedLightLastingSecond */

void display();                            /* 宣告自定顯示函數 */
void calCountDigit(int count);    /* 宣告找出計數值的十位數與個位數值 */
int scanDigitNum;                      /* 實際需要掃描的位數，可為 1 或 2 */
int countTenthsDigit;                  /* 暫存找出的計數值的十位數值 */
int remainder;                            /* 暫存在找出計數值的十位數與個位數值過程產生的餘數 */
int countUnitsDigit;                    /* 暫存找出的計數值的個位數值 */
int redLEDRemainTime;            /* 紅色 LED 亮的剩餘秒數 */

void setup() {
     /* 規劃輸出控制縱向與橫向紅黃綠 LED 的訊號接腳為輸出 */ 
  pinMode(GreenLight_1, OUTPUT);
  pinMode(YellowLight_1, OUTPUT);
  pinMode(RedLight_1, OUTPUT);
  pinMode(GreenLight_2, OUTPUT);
  pinMode(YellowLight_2, OUTPUT);
  pinMode(RedLight_2, OUTPUT);
  
  for (int i = 0; i < 4; i++){
    pinMode(scanPin[i], OUTPUT);    /* 規劃第 5、6、7、8 的掃瞄接腳為輸出 */
    digitalWrite(scanPin[i], 1);             /* 初始狀態：第 5、6、7、8 腳停止掃描，故分別送出邏輯 1     }                                                            訊號*/

  pinMode(dataPin, OUTPUT);           /* 規劃第 10 腳為輸出 */
  pinMode(clockPin, OUTPUT);          /* 規劃第 12 腳為輸出 */
  pinMode(latchPin, OUTPUT);           /* 規劃第 11 腳為輸出 */

  digitalWrite(RedLight_1, HIGH);      /* 初始狀態縱向紅色 LED 亮 */
  digitalWrite(YellowLight_1, LOW);   /* 初始狀態縱向黃色 LED 熄 */
  digitalWrite(GreenLight_1, LOW);    /* 初始狀態縱向綠色 LED 熄 */

  digitalWrite(RedLight_2, LOW);      /* 初始狀態橫向紅色 LED 熄 */
  digitalWrite(YellowLight_2, LOW);   /* 初始狀態橫向黃色 LED 熄 */
  digitalWrite(GreenLight_2, HIGH);   /* 初始狀態橫向綠色 LED 亮 */
  previousTime = millis();                    /* 取得系統從開始至今歷經的時間 (單位毫秒) */ 
  redLEDRemainTime = RedLightLastingSecond-second; /* 找出紅色 LED 亮的剩餘時間 */
}

void loop() {
  nowTime = millis();                              /* 取得系統從開始至今歷經的時間 (單位毫秒) */ 
  display();                                             /* 呼叫顯示函式 */
  if ((nowTime - previousTime) >= 1000 ){  /* 如果已過 1 秒的時間 */
    previousTime = nowTime;
    second++;                                                  /* 歷經的秒數遞加一 */
    redLEDRemainTime = RedLightLastingSecond-second; /* 找出紅色 LED 亮的剩餘秒數 */
     
    if (second == GreenLightLastingSecond ){     /* 若一次週期中綠燈持續亮的時間到 */
      if (RedOnLongitudinal){                                 /* 若輪到縱向紅色 LED 亮 */
        digitalWrite(YellowLight_2, HIGH);              /* 令橫向黃色 LED 亮 */
        digitalWrite(GreenLight_2, LOW);               /* 令橫向綠色 LED 熄 */
      }
      else{                                                             /* 若輪到橫向紅色 LED 亮 */
        digitalWrite(YellowLight_1, HIGH);            /* 令縱向黃色 LED 亮 */
        digitalWrite(GreenLight_1,LOW);              /* 令縱向綠色 LED 熄*/ 
      }
    }
    else if (second == (GreenLightLastingSecond + YellowLightLastingSecond)){ /* 一次週期中綠燈 +
                                                                                                                           黃燈持續亮的時間到 */
      if (RedOnLongitudinal){
        digitalWrite(YellowLight_2, LOW);    /* 令橫向黃色 LED 熄 */
        digitalWrite(RedLight_2, HIGH);       /* 令橫向紅色 LED 亮 */
        digitalWrite(GreenLight_1, HIGH);   /* 令縱向綠色 LED 亮 */
        digitalWrite(RedLight_1, LOW);       /* 令縱向紅色 LED 熄 */
      }
      else{
        digitalWrite(YellowLight_1, LOW);   /* 令橫向黃色 LED 熄 */
        digitalWrite(RedLight_1, HIGH);       /* 令橫向紅色 LED 亮 */
        digitalWrite(GreenLight_2, HIGH);   /* 令縱向綠色 LED 亮 */
        digitalWrite(RedLight_2, LOW);       /* 令縱向紅色 LED 熄 */
      }
      second = 0;                                            /* 秒數歸 0，新的週期開始 */
      redLEDRemainTime = RedLightLastingSecond-second;
      RedOnLongitudinal = !RedOnLongitudinal;   /* 切換縱橫向紅燈亮 */
    }
  }
}

void display(){
  if(redLEDRemainTime >=100)                /* 若紅燈亮的剩餘秒數大於等於 100 */
    return;                                                   /*  返回 (不顯示) */
  calCountDigit(redLEDRemainTime);      /*  找出紅燈亮的剩餘秒數的十位數與個位數 */

  for(int x = 0; x < 4; x++) 
    digitalWrite(scanPin[x], 1);                  /* 清除掃描信號 */ 

  if (RedOnLongitudinal) {                             /* 縱向紅燈亮 */
    for (int i = 0; i < scanDigitNum ; i++){        /* scanDigitNum 為實際掃描位數 */ 
      digitalWrite(latchPin, 0);                          /* 栓鎖信號解除 */ 
      /* 序列傳輸縱向紅燈倒數秒數的第 i 位數數字的七段顯示碼 */   
      shiftOut(dataPin, clockPin, MSBFIRST, sevenSegCode[dataOut[i]]); 
      digitalWrite(latchPin, 1);
      digitalWrite(scanPin[i], 0);                  /* 送出掃描信號給縱向紅燈倒數秒數的第 i 位數 */ 
      delay(2);                                               /* 延遲 2 毫秒 */ 
      digitalWrite(scanPin[i], 1);                   /* 清除縱向紅燈倒數秒數的第 i 位數的掃描信號 */ 
    }
  }
  else{                                                              /* 橫向紅燈亮 */
    for (int i = 0; i < scanDigitNum ; i++){      /* scanDigitNum 為實際掃描位數 */ 
      digitalWrite(latchPin, 0);                           /* 栓鎖信號解除 */ 
      /* 序列傳輸橫向紅燈倒數秒數的第 i 位數數字的七段顯示碼 */   
      shiftOut(dataPin, clockPin, MSBFIRST, sevenSegCode[dataOut[i+2]]); 
      digitalWrite(latchPin, 1);                          /* 送出栓鎖信號 */ 
      digitalWrite(scanPin[i+2], 0);                  /* 送出掃描信號給橫向紅燈倒數秒數的第 i 位數 */ 
      delay(2);                                                   /* 延遲 2 毫秒 */ 
      digitalWrite(scanPin[i+2], 1);                  /* 清除橫向紅燈倒數秒數的第 i 位數的掃描信號 */ 
    }    
  }         
}

void calCountDigit(int count){  
    countTenthsDigit = count/10;              /* 找出計數值的十位數值存入變數 countTenthsDigit */
    remainder =  count%10;                       /* 找出計數值的個位數值存入變數 remainder */
    countUnitsDigit = remainder;              /* 計數值的個位數值暫存於變數 countUnitsDigit */
    if (RedOnLongitudinal) {
      dataOut[1] = countTenthsDigit;      /* 將縱向紅燈倒數秒數的十位數值存入輸出顯示器緩衝區 */
      dataOut[0] = countUnitsDigit;       /* 將縱向紅燈倒數秒數的個位數值存入輸出顯示器緩衝區 */
    }
    else{
      dataOut[3] = countTenthsDigit;      /* 將橫向紅燈倒數秒數的十位數值存入輸出顯示器緩衝區 */
      dataOut[2] = countUnitsDigit;        /* 將縱向紅燈倒數秒數的個位數值存入輸出顯示器緩衝區 */
    }
    if (countTenthsDigit != 0)
        scanDigitNum = 2;         /* 如果秒數值的十位數值不為 0，則掃描位數為 2 個位數 */
    else
        scanDigitNum = 1;         /* 否則掃描位數為 1 個位數 */
}



相關文章

留言

張貼留言

這個網誌中的熱門文章

三段式電子開關電路

作者： Danny Yang
圖片
3-section Digital Subsection Switch   如圖一與圖二所示，為具有相同功能的三段式 電子開關電路。二者的差別在於前者的 組合邏輯電路部分是由及閘、反閘以及互斥或閘所組成，而後者則是僅由反或閘所組成。以下將就其功能、電路動作原理以及組合邏輯設計方法分別說明之。 圖一   三段式 電子開關電路圖 (組合邏輯部分由及閘、反閘以及互斥或閘所組成)
Read more »

陣列 (C++)

作者： Danny Yang
圖片
C++ Arrays  陣列 (array) 是用來儲存相同資料型態元素的集合，陣列中所有元素會使用記憶體中連續的空間來儲存，且陣列必須明確定義其大小，執行期間不能更改。  一維陣列 (One Dimensional Arrays) 一維陣列可視為一組線性系列元素。假設有一組整數資料：10 、20、30 、40 以及 50 存入一名為 A 的陣列，其對應的索引值、位址以及元素名稱如圖一所示。在此，每一整數佔記憶體空間為 4 個位元組 (Bytes)，且 C/C++ 語言中陣列的起始索引值為 0。此ㄧ維陣列元素 A[0] 的位址，被稱為 基底位址 (base address)。
Read more »

首數、尾數與位數

作者： Danny Yang
圖片
科學記號 (Scientific Notation) 常被用來簡潔地表示極大或極小的數值以方便分析，其表示法為  $$a \times 10^n \;\;\; (1 \le |\;a\;|<10，n \;為整數 )$$ 例如一個大於 $1$ 的數： $673,000$，若以科學記號來表示，可寫成 $6.73 \times 10^5$，將其取對數，可得 $5+log\;6.73$，其中 $5$ 為對數值整數的部分，$log\;6.73$ 為對數值小數的部分。我們可以觀察到 $673,000$ 為 6 位數，剛好是其科學記號表示法中的指數 $5$ 加 $1$ 或是其對數值整數部分 (即 $5$) 加 $1$ 的結果；又一個小於 $1$ 的數：$0.00673$ 的科學記號為 $6.73 \times 10^{-3}$，對數值為 $-3+log\;6.73$，我們也可以觀察到該數在小數點第 $3$ 位開始數字不為 $0$，剛好是其科學記號表示法中的指數 $-3$ 的絕對值或是其對數值整數部分的絕對值。
Read more »

分壓偏壓 BJT 放大電路的直流分析及其近似解的條件

作者： Danny Yang
圖片
  DC Analysis of a Voltage Divider BJT Bias Circuit and Its Conditions of Approximate Method  如圖一所示為一 分壓偏壓 BJT 放大電路  (Voltage Divider BJT Bias Circuit)，下面我們將分別介紹如何以精確分析法以及近似解方法來進行該類型放大電路的直流分析，同時也會說明使用近似解的先決條件為何。 圖一     分壓偏壓 BJT 放大電路 精確分析法 (Exact Method) 要作直流分析，如圖二所示得先將圖一的 分壓偏壓 BJT 放大電路中 電晶體基極左側部分，進行 戴維寧等效電路 ( Thévenin Equivalent Network) 的轉換，以方便分析。
Read more »

MOSFET 共汲極放大電路 (源極隨耦器) 小訊號分析

作者： Danny Yang
圖片
MOSFET Common Drain Amplifier  (Source Follower): Small Signal Analysis    如圖一所示，為一 MOSFET 共汲極放大電路  (Common Drain Amplifier) ，此電路又被稱為 源極隨耦器 (Source Follower)。其特點是輸入阻抗大，輸出阻抗小，且電壓增益小於 1 但接近於 1 ，故在多級放大器中，常被作為電壓緩衝級用來驅動較小的負載輸出。 圖一     MOSFET 共汲極放大電路
Read more »

為什麼理想的 OPA 電壓放大器有虛短路與虛斷路現象

作者： Danny Yang
圖片
採負回授方式連接的運算放大器 (Operational Amplifier，簡稱 OPA) 可作為電壓放大之用。而欲被放大的電壓輸入信號若輸入於 OPA 的負輸入端 ($v_-$) ，所形成的電壓放大器被稱為 反相 OPA 電壓放大器 (Inverting Operational Amplifier)；反之，若電壓輸入信號輸入於 OPA 的正輸入端  ($v_+$)，則被稱為 非反相 OPA 電壓放大器 (Non-inverting Operational Amplifier)。無論是反相 OPA 電壓放大器或是非反相 OPA 電壓放大器，其 OPA 的正負輸入端，在負回授方式連接的情況下皆存在有 虛短路 (Virtual Short) 與 虛斷路 (Virtual Break) 現象。 所謂虛短路指的是理想的 OPA 放大器在負回授的情況下，OPA 的正輸入端與負輸入端的電位差極小，小至接近於零的現象。因此，在簡化分析時常可將二者的電位視為相等，猶如兩端短路ㄧ般；而所謂虛斷路指的是 OPA 放大器在負回授的情況下，流入 OPA 本身輸入端的電流極小，小至接近於零，以致於可將 OPA 內部連接輸入電阻的兩輸入端視為斷路的現象。 以下將分別針對反相 OPA 電壓放大器以及非反相 OPA 電壓放大器，證明虛短路與虛斷路現象之存在。且上述的二現象若存在，則在推導反相與非反相 OPA 電壓放大器的增益公式時，過程將會容易許多。
Read more »

具有倒數計時自動回復功能的行人穿越道號誌控制電路

作者： Danny Yang
圖片
  A Pedestrian Crossing Safety Circuit with Self-resetting Countdown Timer 先前的文章 簡易行人穿越道號誌控制電路 ，行人必須在安全穿越馬路後，手動按下「回復」按鈕，路口的燈號才會由亮紅燈回復到閃黃燈。本文以先前的簡易號誌控制電路為基礎，進一步將電路修改為一具有倒數計時 自動 回復功能的行人穿越道號誌控制電路，如圖一所示。 電路功能 平時路口閃黃燈，當有行人要安全地穿越車道時，可按下「通行」按鈕，按下後路口黃燈熄滅，轉而亮紅燈，行駛的車輛停止行進等待行人通過。此時， 顯示器 會顯示倒數計時起始秒數 30 秒，並開始倒數計時。ㄧ旦倒數計時至 0 ，路口紅燈就熄滅，轉而閃黃燈，原 停止的車輛就可以恢復行駛。 圖一      具有自動倒數計時回復功能的行人穿越道號誌控制電路 (七段顯示器為共陰型) 動作原理 電源打開瞬間， NOR Gate IC 4001 的第 5 腳會接收到邏輯 "1" 的訊號，且無論其第 6 腳接收到的訊號為何，第 4 腳會輸出邏輯 "0" 給 IC 4001 的第 2 與第 1 腳，導致其第 3 腳輸出邏輯 "1" 給 D 型正反器 4013 的第 4 腳 ($CLR$)。此時在第 6 腳 ($PR$) 恆為接地的情況下，IC 4013 的第 1 腳 ($Q$) 會輸出邏輯 "0"，使得紅色 LED 熄滅，且圖中左邊的 555 無穩態振盪器輸出的矩型波的反相波會出現在 IC 4001 的第 11 腳，驅動黃色 LED 閃爍。 電源穩定後，IC 4001 的第 5 腳會接收到邏輯 "0" 的訊號；同時因為左側的 十進制上下數計數器 IC 4029 並未有借位輸出，所以第 7 腳 ($\overline {CARRY \ \ OUT}$) 會輸出邏輯 "1" 給 IC 4001 的第 8 與第 9 腳，導致 IC 4001 的第 10 腳輸出邏輯 "0" 給 IC 4001 的第 6 腳，使得最終 IC 4001 的第 3 腳輸出邏輯 "0" 給 D 型正反器 IC 4013 的第 4 腳 ($CLR$)。在第 6 ...
Read more »